base

言語バージョン

AS2 and AS3.

語法

... base:object, ...

パラメーター

object:Object または Array — 新規のトウィーンを宣言するためのプロパティやパラメーターを含む配列またはオブジェクト。このオブジェクトは新規トウィーンの"基礎"となり、トウィーンの継承や、あるトゥイーンのプロパティやパラメーターを再利用するためなどに使われる。

用例

// baseパラメーターなしで、myMovieClipをフェードアウトさせるトウィーンオブジェクトを使用する(AS2)
var myFade:Object = {_alpha:0, time:1};
Tweener.addTween(myMovieClip, myFade);

// baseパラメーターを使って、上記と同じ事をする
var myFade:Object = {_alpha:0, time:1};
Tweener.addTween(myMovieClip, {base:myFade});

// baseパラメーターを使って、元の「base」オブジェクトと異なるtimeを設定したフェードアウトアニメーションを設定する
var myFade:Object = {_alpha:0, time:1};
Tweener.addTween(myMovieClip, {base:myFade, time:2});
// 複数の異なるオブジェクトを結合させることも可能
var myFade:Object = {_alpha:0, time:1};
var myFadeLong:Object = {base:myFade, time:10};
var myFadeShort:Object = {base:myFade, time:0.2};
Tweener.addTween(myMovieClip1, myFadeLong);
Tweener.addTween(myMovieClip2, myFadeShort);
// 「base」パラメーターの値はaddTween()メソッドが実行される時に読み出される。
// このため、baseパラメーターにオブジェクトが設定された後に、オリジナルのbaseの値を変更することも可能である。
// 下記の例では、_alphaの値が10秒間かけて50に変化する。
var myFade:Object = {_alpha:0, time:1};
var myFadeLong:Object = {base:myFade, time:10};
myFade._alpha = 50;
Tweener.addTween(myMovieClip, myFadeLong);
// baseオブジェクトのプロパティを無視し、デフォルト値に戻すためには、それらのプロパティ値をnullに設定する。
var myDelayedFade:Object = {_alpha:0, time:1, delay:1};
var myFade:Object = {base:myDelayedFade, delay:null};
Tweener.addTween(myMovieClip, myFade);
// baseオブジェクトの配列を使った例
var myFade:Object = {_alpha:0, time:1};
var myFadeLong:Object = {time:10};
Tweener.addTween(myMovieClip1, {base:[myFade, myFadeLong]});
// 上記と同じ事をネストしたbaseオブジェクトを使って実現した例
var myFade:Object = {_alpha:0, time:1};
var myFadeLong:Object = {base:myFade, time:10};
Tweener.addTween(myMovieClip1, myFadeLong);

	

メニューの表示について

このページの左側にメニューが表示されていない場合は、ここをクリックするとメニューを表示させることができます。

本ドキュメントについて