addTween()

言語バージョン

AS2 and AS3.

語法

Tweener.addTween(target:Object, tweeningParameters:Object):Void

パラメーター

target:Object — トゥイーンを実行する対象のオブジェクト。通常はMovieClip, TextField, Sound インスタンス、あるいはトゥイーンさせる数値プロパティを有するカスタムオブジェクト。

tweeningParameters:Object — 対象オブジェクトのトゥイーンさせたいプロパティと、その最終値が指定されたオブジェクト。特殊なプロパティや、tweeningパラメーターを定義する際に使われる組み込み式のTweenerプロパティも指定可能。tweeningのレシピのようなもので、何をどのようにトゥイーンさせるのかを宣言する。

解説

Tweenerの核。新しいトゥイーンを生成するときに使われる。あるオブジェクトの任意のプロパティを、任意の所要時間で、任意の値に変更する。例えば、myMC_xプロパティをリニアトランジション方程式(?)を使って2秒間で100にする、というようなMovieClipのスライドアニメーションを実行する時などに使う。

このメソッドのシンタックスはとても緩い。ハードコードされたパラメーターはわずかで、膨大なトランジションオプションを宣言することが可能となっている。

非常に多くのオプションが利用可能となっているので、tweeningパラメーターのページで個別の特徴についての記事を読んだり、特殊なプロパティのページを見て一般的でないプロパティについて学習するといいだろう。

返り値

なし

用例

// ムービークリップを指定位置に0.5秒でスライドさせる (AS2)
Tweener.addTween(myMovieClip, {_x:10, time:0.5});
// ムービークリップを指定位置に0.5秒でスライドさせる (AS3)
Tweener.addTween(myMovieClip, {x:10, time:0.5});
// ムービークリップを2秒でフェードイン (AS2)
myMovieClip._alpha = 0;
Tweener.addTween(myMovieClip, {_alpha:100, time:2});
// ムービークリップを2秒でフェードイン (AS3)
myMovieClip.alpha = 0;
Tweener.addTween(myMovieClip, {alpha:1, time:2});
// _xと_alphaの値を同時に変更
Tweener.addTween(myMovieClip, {_x:10, _alpha:100, time:0.5});
// 他のtransitionタイプを使ってtweening
Tweener.addTween(myTextField, {_y:200, time:0.7, transition:"linear"});
// アニメーションシークエンスを演出するために遅延を設定
Tweener.addTween(myMovieClip, {_x:20, time:0.5});
Tweener.addTween(myMovieClip, {_x:0, time:0.5, delay: 0.5});
// tweenerの「テンプレート」を使用
var fadeIn:Object = {_alpha:100, time:1};
Tweener.addTween(myMovieClip, fadeIn);
// イベントを指定して、フェードアウトの後に不可視化(通常の関数)
disappear = function() {
	this._visible = false;
};
Tweener.addTween(myMovieClip, {_alpha:0, time:1, onComplete:disappear});
// イベントを指定して、フェードアウトの後に不可視化(匿名関数)
Tweener.addTween(myMovieClip, {_alpha:0, time:1, onComplete:function() { this._visible = false; }});
// イベントを指定して、フェードアウトの後に不可視化(特殊なプロパティの_autoAlphaを使って)
Tweener.addTween(myMovieClip, {_autoAlpha:0, time:1});
// より複雑なイベントの例
fGo = function() { trace ("I'll go!"); };
fGoing = function() { trace ("I'm going!"); };
fGone = function() { trace ("I'm gone!"); };
Tweener.addTween(myMovieClip, {_alpha:0, time:1, onStart:fGo, onUpdate:fGoing, onComplete:fGone});
// 遅延なしに即座に新たな値を適用
Tweener.addTween(myMovieClip, {_alpha:100});
// 変数やプロパティに関係のないその他の特殊なプロパティを使った例
Tweener.addTween(mySoundObject, {_sound_volume:100, time:1});
Tweener.addTween(myMovieClip, {_frame:10, time:2.5});

参照

pauseTweens, resumeTweens, removeTweens, removeAllTweens, addCaller, Tweening parameters, Special properties

メニューの表示について

このページの左側にメニューが表示されていない場合は、ここをクリックするとメニューを表示させることができます。

本ドキュメントについて